> For the complete documentation index, see [llms.txt](https://kdoore.gitbook.io/cs1335/llms.txt). Markdown versions of documentation pages are available by appending `.md` to page URLs; this page is available as [Markdown](https://kdoore.gitbook.io/cs1335/grid-based-designs/pshapes-in-grid-layout/truchet-tiling.md).

# Truchet Tiling

Truchet Tiling

The code below shows an example of Truchet Tiling -[ Wikipedia](https://en.wikipedia.org/wiki/Truchet_tiles) The

![](/files/-M0-Kg676NJ-LE5gXClD)

## Code Example

This code example shows how we can use a 1-Dimensional array of PShapes to create a grid arrangement of shapes.

```java
PShape[] shapes;
int colWidth=30;
int rowHeight = 30;
void setup() {
  size(600, 600);
  colorMode(HSB, 360, 100, 100);
  background(200, 100, 100);
  strokeJoin(ROUND);
  stroke(0);
  strokeWeight(15);
  shapes = populateArray(colWidth, rowHeight);
  drawGrid(shapes, colWidth, rowHeight);
}

PShape[] populateArray( float colWidth, float rowHeight) {
  PShape[] shapes;
  int numRows =int( height/rowHeight);
  int numCols =int( width/colWidth);
  shapes = new PShape[numRows * numCols];
  PShape block1 = createBlock( colWidth, rowHeight, true);
  PShape block2 = createBlock( colWidth, rowHeight, false);
  for ( int i=0; i< numRows* numCols; i++) {
    float rand = random(0, 2);
    if ( rand > 1) { //flip a coin
      shapes[i]= block1; ///use block 1
    } else {
      shapes[i]= block2;
    }
  }
  return shapes;
}


PShape createBlock( float xSize, float ySize, boolean mode ) {
  PShape s2;
  s2=createShape();
  s2.beginShape();
  if ( mode == true) { //arrangement 0
    s2.vertex( 0, 0);
    s2.vertex( xSize, ySize);
  } else {
    s2.vertex( xSize, 0);
    s2.vertex( 0, ySize);
  }
  s2.endShape();
  return s2;
}


void drawGrid(PShape[] shapes, int colWidth, int rowHeight ) {
  int numRows = height/rowHeight;
  int numCols = width/colWidth;
  int xPos=0;
  int yPos = 0;
  int k=0;
  for ( int i=0; i< numRows; i++) { //rows
    for ( int j=0; j< numCols; j++) { //cols
      PShape s =shapes[k] ;
      shape( s, xPos, yPos);
      xPos += colWidth;
      k++;
    }
    xPos=0;
    yPos += rowHeight;
  }
}

void draw() { //draw must be included for mouseReleased event function to work
}

void mouseReleased() {
  background(random(360), 100,100);
  shapes = populateArray(colWidth, rowHeight);
  drawGrid(shapes, colWidth, rowHeight);
}
```


---

# Agent Instructions
This documentation is published with GitBook. GitBook is the documentation platform designed so that both humans and AI agents can read, navigate, and reason over technical content effectively. Learn more at gitbook.com.

## Querying This Documentation
If you need additional information that is not directly available in this page, you can query the documentation dynamically by asking a question.

Perform an HTTP GET request on the current page URL with the `ask` query parameter:

```
GET https://kdoore.gitbook.io/cs1335/grid-based-designs/pshapes-in-grid-layout/truchet-tiling.md?ask=<question>
```

The question should be specific, self-contained, and written in natural language.
The response will contain a direct answer to the question and relevant excerpts and sources from the documentation.

Use this mechanism when the answer is not explicitly present in the current page, you need clarification or additional context, or you want to retrieve related documentation sections.